Top Info
najistotniejsze informacje z tematu |
|
| Zobacz poprzedni temat :: Zobacz następny temat |
| Autor |
Wiadomość |
damjanek 
Weteran
Dołączył: 12 Kwi 2003
Posty: 381
Skąd: Poznań
Wiek: 39 lat(a)
|
 Wysłany: 04 Cze 2003 19:19 Temat postu: Foobar <---- tagz configuration |
 |
|
heh....ostatnio nudzilo mi sie i zaczelem sie bawic w robienie tzw. tagow do foobar. ogolnie fajna sprawa....
postanowilem, ze podziele sie z innymi moimi dokonaniami, ale akurat moje dzielo jest w trakcie tworzenia, wiec narazie wrzuce kod, ktorego ja aktualnie uzywam... walek polega na tym, zeby w menu Foobar\preferences wybrac display\title formatting i tam zakladke playlist i wkleic ten kod:
| Kod: |
//
// set colours
//
$if(%_isplaying%,
$puts(col_plno,FFFFFF|FFFFFF)
$puts(col_trno,7EBABE|FFFFFF)
$puts(col_length,0000FF|FFFFFF)
$puts(col_title,FFFFFF|FFFFFF)
$puts(col_light,FFFFFF|FFFFFF)
$puts(col_trans_light,FFFFFF|FFFFFF)
$puts(col_trans_dark,000000|000000)
$if($or(%singletrack%,%various%),
$puts(col_artist,FFFFFF|FFFFFF)
,
$puts(col_artist,55DD00|7EBABE)
)
,
$puts(col_plno,7EBABE|7EBABE)
$puts(col_trno,0055DD|7EBABE)
$puts(col_length,CCCCCC|FFFFFF)
$puts(col_title,CC9922|7EBABE)
$puts(col_light,808080|808080)
$puts(col_trans_light,808080|808080)
$puts(col_trans_dark,220000|220000)
$if($or(%singletrack%,%various%),
$puts(col_artist,99FF55|7EBABE)
,
$puts(col_artist,55DD00|7EBABE)
)
)
$puts(col_playing,FFFFFF|FFFFFF)
$puts(col_genre,996600|7EBABE)
$puts(col_date,996600|7EBABE)
$puts(col_album,CC9922|7EBABE)
$puts(col_dark,404040|000000)
$puts(col_disc,0080FF|0080FF)
$puts(col_bonus,808000|808000)
$puts(col_sep,7EBABE|7EBABE)
$puts(col_a_gain,505050|505050)
$puts(col_t_gain,808080|808080)
$puts(col_station,2299CC|FFFFFF)
//
// set variables
//
$puts(symb_playing,'>>>>>>')
$puts(symb_a_gain,'[A]')
$puts(symb_t_gain,'[T]')
$puts(text_plno,%_playlist_number%)
$puts(text_station,%station%' ')
$puts(text_bonus,*Bonus Track*)
$puts(text_album,%album%[ %volume%])
$puts(text_disc,[Disc %disc% ][''%discname%''])
$if(%date%,
$puts(text_date,%date%)
,
$puts(text_date,'ÄÄÄÄ')
)
$if(%various%,
$puts(text_artist,Various Artists)
,
$puts(text_artist,%artist%)
)
$puts(len_date,$len($get(text_date)))
$puts(len_station,$len($get(text_station)))
$puts(len_album,$len($get(text_album)))
$puts(len_disc,$len($get(text_disc)))
$puts(len_artist,$len($get(text_artist)))
$puts(len_divider_point,15)
$puts(len_min,32)
$puts(len_tag,$len($longest($longest($longest($get(text_artist),$get(text_album)),$get(text_disc)),%genre%)))
$if(%singletrack%,
$puts(space,$get(len_min))
,
$puts(space,$ifgreater($get(len_tag),$get(len_min),$get(len_tag),$get(len_min)))
)
$if(%various%,
$puts(len_divider,$sub(80,$add($len(%artist%),$add(3,$add($get(space),$len(%title%))))))
,
$puts(len_divider,$sub(80,$add($get(space),$len(%title%))))
)
//
// apply colours
//
$if(%date%,
$puts(text_date,$get(col_date)%date%)
,
$puts(text_date,$get(col_sep)'ÄÄÄÄ')
)
$puts(text_plno,$get(col_plno)$get(text_plno))
$puts(symb_playing,$transition($get(symb_playing),$get(col_trans_dark),$get(col_trans_light)))
$puts(text_single_artist,$repeat('
',$add($sub($get(space),$get(len_artist)),1))$get(col_artist)$get(text_artist)' ')
$puts(text_bonus,$get(col_bonus)$get(text_bonus))
$puts(text_album,$get(col_album)$get(text_album)$repeat(' ',$sub($get(space),$get(len_album))))
$puts(text_artist,$get(col_artist)$get(text_artist)$repeat(' ',$sub($get(space),$get(len_artist))))
$puts(text_disc,$get(col_disc)$get(text_disc)$repeat(' ',$sub($get(space),$get(len_disc))))
$puts(text_station,$get(col_station)$cut($get(text_station),$get(space))$repeat('
',$sub($get(space),$get(len_station))))
$puts(text_genre,$get(col_genre)%genre%$repeat(' ',$sub($get(space),$len(%genre%))))
$puts(text_date,$get(text_date)$transition($repeat(Ä,$get(len_divider_point)),$get(col_sep),$get(col_trans_dark)
)$repeat(' ',$sub($sub($get(space),$get(len_date)),$get(len_divider_point))))
$puts(text_divider,$get(col_sep)$repeat(Ä,$get(len_divider))$transition($repeat(Ä,$get(len_divider_point)),$get(
col_sep),$get(col_trans_dark)))
//
// set playlist number formatting
//
$puts(plno,$get(col_sep)Ă$get(text_plno)$get(col_sep)´)
$ifgreater(%_playlist_number%,999,
,$puts(plno,$get(col_sep)Ă$get(col_dark)'0'$get(text_plno)$get(col_sep)´)
)
$ifgreater(%_playlist_number%,99,
,$puts(plno,$get(col_sep)Ă$get(col_dark)'00'$get(text_plno)$get(col_sep)´)
)
$ifgreater(%_playlist_number%,9,
,$puts(plno,$get(col_sep)Ă$get(col_dark)'000'$get(text_plno)$get(col_sep)´)
)
//
// set album/artist formatting
//
$if($strcmp($num(%tracknumber%,1),1),
$puts(album,$get(col_sep)Ú$repeat(Ä,$get(space))Ä)
)
$if($strcmp($num(%tracknumber%,1),2),
$puts(album,$get(col_sep)Ă$get(text_artist)' ')
)
$if($strcmp($num(%tracknumber%,1),3),
$puts(album,$get(col_sep)Ă$get(text_album)' ')
)
$if($strcmp($num(%tracknumber%,1),4),
$if($strcmp(0,$get(len_disc)),
$puts(album,$get(col_sep)Ă$get(text_genre)' ')
,
$puts(album,$get(col_sep)Ă$get(text_disc)' ')
)
)
$if($strcmp($num(%tracknumber%,1),5),
$if($strcmp(0,$get(len_disc)),
$puts(album,$get(col_sep)Ŕ$get(text_date)' ')
,
$puts(album,$get(col_sep)Ă$get(text_genre)' ')
)
)
$if($strcmp($num(%tracknumber%,1),6),
$if($strcmp(0,$get(len_disc)),
$puts(album,' '$repeat(' ',$get(space))' ')
,
$puts(album,$get(col_sep)Ŕ$get(text_date)' ')
)
)
$ifgreater(%tracknumber%,6,
$puts(album,' '$repeat(' ',$get(space))' '),
)
// if no tracknumber
$if(%tracknumber%,,
$if(%station%,
$puts(album,$get(col_sep)-$get(text_station)' ')
,
$if(%artist%,
$puts(album,$get(col_sep)$get(text_artist)' ')
,
$puts(album,$get(col_sep)%_filename%' ')
)
)
)
// if %singletrack%
$if(%singletrack%,
$puts(album,$get(text_single_artist))
)
//
// set tracknumber formatting
//
$ifgreater(%tracknumber%,9,
$puts(tracknumber,$get(col_trno)$num(%tracknumber%,2))
,
$puts(tracknumber,$get(col_dark)0$get(col_trno)$num(%tracknumber%,1))
)
$if($strcmp($num(%tracknumber%,1),1),
$puts(tracknumber,$get(col_sep)Â$get(tracknumber)$get(col_sep)Â)
)
$ifgreater(%tracknumber%,1,
$if(%lasttrack%,
$puts(tracknumber,$get(col_sep)Ŕ$get(tracknumber)$get(col_sep)Ů)
,
$puts(tracknumber,$get(col_sep)Ă$get(tracknumber)$get(col_sep)ł)
),
)
$if(%tracknumber%,,
$if(%artist%,
$puts(tracknumber,$get(col_sep)' ÄÄ '$get(col_sep))
,
$puts(tracknumber,)
)
)
$if($and(%singletrack%,%tracknumber%),
$puts(tracknumber,$get(col_sep)' ÄÄ '$get(col_sep))
)
//
// set title formatting
//
$if(%various%,
$puts(title,$get(col_artist)%artist%$get(col_dark)' - '$get(col_title)%title%$get(col_dark)[ %version%])
,
$puts(title,$get(col_title)%title%$get(col_dark)[ %version%])
)
$if(%bonustrack%,$puts(title,$get(title) $get(col_bonus)$get(text_bonus)))
//
// set divider
//
$if($and($strcmp($num(%tracknumber%,1),1),$not(%singletrack%)),
$puts(divider,$get(text_divider))
)
//
//set ReplayGain info
//
$puts(rpg,
$if(%__replaygain_track_gain%,
$if(%__replaygain_album_gain%,
$get(col_a_gain)$if(%__replaygain_album_gain%,
$get(symb_a_gain)),
$get(col_t_gain)$if(%__replaygain_track_gain%,$get(symb_t_gain))),
$puts(width_gain_symb,$len($longest($get(symb_a_gain),$get(symb_t_gain))))
$repeat(' ',$get(width_gain_symb))
))
//
// set length
//
$puts(length,$get(col_length)$pad_right(%_length%,5))
//
//set now playing symbol
//
$puts(playing,$get(col_playing)$if(%_isplaying%,$get(symb_playing)))
//
// set spacer tracknumber title
//
$if($strcmp($num(%tracknumber%,1),1),
$puts(spacer_trno_title,$get(col_sep)Ä)
,
$puts(spacer_trno_title,' ')
)
$if($and(%singletrack%,%tracknumber%),
$puts(spacer_trno_title,' ')
)
//
// remove underscore
//
$replace(
//
// create string
//
$get(plno)
' '
$get(album)
$get(tracknumber)
$get(spacer_trno_title)
$get(title)
$get(divider)
$char(9)
$get(playing)
$get(length)
$get(rpg)
//
// end remove underscore
//
,_, )
|
wiem.....to troche przydlugawe, ale jet to fajna sprawa.....
zeby poprawnie sie wszystko wyswietlalo, nalezy wybrac czcionke dla playlisty lime, wielkosc czcionki 6.... i jeszcze jedno:
| Kod: |
//*****Start Configure**************
// Variables
$puts(spacer_symb,' ')
$puts(spacer_width,2)
$puts(prog_symb1,'Ű')
$puts(prog_symb2,'Ű')
$puts(prog_length,25)
$puts(paused_symb,'PAUSED')
$puts(cuefile_symb,'Cue File')
// Colors
$puts(paused_color,0000FF)
$puts(streaming_color,008800)
$puts(col_prog1,CC8822)
$puts(col_prog2,440000)
// Calculation
$puts(prog1,$get(col_prog1)$get(prog_symb1))
$puts(prog2,$get(col_prog2)$get(prog_symb2))
$puts(spacer,$repeat($get(spacer_symb),$get(spacer_width)))
//*****End Configure****************
//Show if it is a cue file
$if(%__cue_audiotype%,$get(cuefile_symb)$get(spacer),)
//Draw 'Streaming' for streaming (radio...)
$if(%_time_total%,,$get(streaming_color)'Streaming'$get(spacer))
//Draw codec
$if(%__codec%,%__codec%,)
//Draw bitrate
$if(%__bitrate%,$get(spacer)%__bitrate%'kbps',)
//Draw extra info, if any
$if(%__extrainfo%,$get(spacer_symb)%__extrainfo%,)
//Draw samplerate
$if(%__samplerate%,$get(spacer)$cut(%__samplerate%,2)'kHz',)
//Draw channels
$if(%__channels%,$get(spacer)$ifgreater(%__channels%,2,%__channels%ch,$ifgreater(%__channels%,1,Stereo,Mono)) ,)
//Draw ReplayGain info
$if(%__replaygain_track_gain%,
$get(spacer)$if(%__replaygain_album_gain%,
$if(%__replaygain_album_gain%,
%__replaygain_album_gain%),
$if(%__replaygain_track_gain%,%__replaygain_track_gain%)),
)
//Draw progress bar (checking total because of streaming)
$if(%_time_total_seconds%,$get(spacer)
$progress2(%_time_elapsed_seconds%,%_time_total_seconds%,$get(prog_length),$get(prog1),$get(prog2)),)
//Draw progress in % (checking total because of streaming)
$if(%_time_total_seconds%,' ='$pad_right($muldiv(%_time_elapsed_seconds%,100,%_time_total_seconds%),3)'%',)
//Draw 'Listened for:' for streaming (radio...)
$if(%_time_total%,,$get(spacer)$get(spacer)$get(streaming_color)'Listened for:')
//Draw time (checking total and remaining because of streaming)
$get(spacer)
%_time_elapsed%
$if(%_time_total%,'/'%_time_total%,)
$if(%_time_remaining%,$get(spacer)' [R: '%_time_remaining%']',)
//Right adjust from now on
$char(9)
//Display "PAUSED" if track is paused
$if(%_ispaused%,$get(spacer)$get(paused_color)$get(paused_symb),)
|
ten kod wrzuc do zakladki status bar i tez zmienic czcionke dla status bara na lime rozmiar 6.....
licze ze nie tylko ja mam jakiegos fiola na punkcie foo....
_________________
...wiem którędy wiedzie mnie moja droga... |
|
| Powrót do góry |
|
 |
Adv Bot
Dołączył: 01 Sty 1970
Posty:
|
| Wysłany: 12 Mar 2025 5:51 Temat postu: Reklama |
|
|
TechnoVolt oferuje energooszczędne oświetlenie hal i pomieszczeń magazynowo-produkcyjnych w profesjonalnym wykonaniu.
Wieloletnie doświadczenie i atrakcyjne ceny gwarantują u nas najlepszą ofertę na rynku w branży elektrycznej.
Stosujemy najnowocześniejsze technologie i wysokiej jakości produkty.
Dla inwestycji naszych klientów dostarczamy i wykonujemy nowoczesne oświetlenie energooszczędne (LED) z zastosowaniem opraw: dekoracyjnych, rastrowych, hermetycznych, przemysłowych, projektorów oraz linii świetlnych.
Kontakt z nami i informacje na naszej stronie www.TechnoVolt.pl
*** NOWOŚĆ ***
Kompensacja mocy biernej - obniż swoje rachunki za prąd!
Usługa dostępna na terenie całego kraju
Zredukuj opłaty za prąd ::
Płać mniej za prąd
|
|
| Powrót do góry |
|
|
ciumi
Gaduła
Dołączył: 19 Sty 2003
Posty: 38
Skąd: lodz(studia) pochodze z wloclawk
|
| Wysłany: 17 Cze 2003 0:06 Temat postu: |
|
|
status bar dziala fajnie, tylko sobie zmniejszylem dlugosc progresa do 5
natomiast playlista sie chrzani.. moze cos zle wlepiam albo jakies przekalamania sa w kodzia.. 
pozdrowki
_________________
-=| cIuMi |=- |
|
| Powrót do góry |
|
|
g79
Niemowa
Dołączył: 22 Cze 2003
Posty: 6
|
|
| Powrót do góry |
|
|
mleko
Niemowa
Dołączył: 23 Sie 2003
Posty: 1
|
| Wysłany: 29 Sie 2003 12:33 Temat postu: hmmm |
|
|
może nie mam jakiegoś odkrywczego formatowania ale
playlista:
| Cytat: |
$if(%_isplaying%,0000FF,000000)
'[]' $num(%_playlist_number%,3).
'[]' $if(%artist%,%artist%,)
$if( $if(%title%,%title%, ...), '[]' $if(%title%,%title%, ...),%_filename_ext% '[]' )
[ '[]' %_length% ]
status bar:
// COLORS
$puts(col_1,038800|038800)
$puts(col_3,D0D0D0|D0D0D0)
$puts(col_2,A0A000|D0D0D0)
$puts(col_4,0000DD|0000B3)
$puts(col_5,006622|D0D0D0)
FF0000
[%artist% - ]
000000
FF00FF
$if(%title%,['[''] ']%title%,%_filename_ext%)
000000
333333
-%_time_remaining%[ / %_time_total%]
// PROGRESS BAR WIDTH
$puts(len,$strrchr($progress2(%_time_elapsed_seconds%,
%_time_total_seconds%,70,a,b),a))
$char(9)
// BAR
$transition($repeat($char(1472),$get(len)),$get(col_2),$get(col_4),0,70)
$repeat($char(1472),$sub(70,$get(len)))
118811
[ %__bitrate%kbps ]
000000
|
|
|
| Powrót do góry |
|
|
damjanek
Weteran
Dołączył: 12 Kwi 2003
Posty: 381
Skąd: Poznań
Wiek: 39 lat(a)
|
| Wysłany: 29 Sie 2003 14:55 Temat postu: |
|
|
ostatnio sie nudzilem i postanowilem stworzyc wlasne formatowanie......
skonczylem je robic moze z 15min temu, wiec nie wszystko jeszcze w nim umiescilem, bo mi czasu i pomyslow braklo......
uzywam do tego czcionki lime rozmiar 8.....
kolor pl backgrounda= true-black (000000)
czekam na jakies sugestie itd.....wiem ze nie wyglada to cudnie, ale na pewno jest wygodne ze wzgledu na fakt ze wystarcza 4 piosenki w albumie zeby wszystko bylo wyswietlane poprawnie.....
pozdrawiam
:B is playin: Red Hot Chilli Peppers [Californication #01] Around The World
_________________
...wiem którędy wiedzie mnie moja droga... |
|
| Powrót do góry |
|
|
|
|
Nie możesz pisać nowych tematów
Nie możesz odpowiadać w tematach
Nie możesz zmieniać swoich postów
Nie możesz usuwać swoich postów
Nie możesz głosować w ankietach
|
|
Strona główna
REGULAMIN
Użytkownicy
Grupy
phpBB forum FAQ
